基礎から学ぶシステムトレード
シストレブログ人気ランキング  

シストレ徹底攻略シストレマスターへの道ワールド・トレーディング・エッジ基礎から学ぶシステムトレードシストレニュースシストレツールシストレナビTOPへ

 

著書のご紹介

2010年09月13日(月)

MQL5でEA(3) [MetaTrader5]

前回はトレード関数OrderSend()の簡単な使い方について説明しました。

今回は、EAに組み込む際に使いやすいように、OrderSend()を実行する手続きをまとめて関数の形にしてみます。

その前にMQL5というかMT5になってオープンポジションの扱いが大きく変わったので、それについて説明しておきましょう。

MQL4では、OrderSend()で送信した成行や指値、逆指値などのオーダーは、個別にチケット番号が振られ、別々に扱われていました。

オープンポジションについても同じで、次のように同じ通貨ペアで複数のポジションを個別に見ることができました。また買いポジションと売りポジションを同時に取る両建ても可能でした。

MQL4のオープンポジション
ポジション1:USD/JPY 0.1 ロット 買いポジション
ポジション2:USD/JPY 0.1 ロット 買いポジション
ポジション3:USD/JPY 0.1 ロット 買いポジション
ポジション4:USD/JPY 0.1 ロット 売りポジション


ところが、MQL5では、指値や逆指値の待機オーダーは別々に扱われますが、一旦約定してオープンポジションになってしまうと、それらは通貨ペア毎にまとめて扱われます。

つまり、上の4ポジションは、売りポジションと買いポジションが相殺され、さらに残りの2つの買いポジションもまとめられて1つのポジション
MQL5のオープンポジション
ポジション:USD/JPY 0.2 ロット 買いポジション

だけになってしまいます。

ここでは、MQL5特有のポジションの扱いを頭において、売買システムを考えていくことにします。

まずは成行でポジションを建てる関数を作ってみます。リストを以下に示します。

// 成行オーダー
void OrderSendMarket(ENUM_ORDER_TYPE type, double lots)
{
MqlTradeRequest request;
MqlTradeResult result;

request.action = TRADE_ACTION_DEAL;
request.symbol = _Symbol;
if(type == ORDER_TYPE_BUY) request.price = Ask;
else if(type == ORDER_TYPE_SELL) request.price = Bid;
request.deviation = Slippage;
request.volume = lots;
request.type = type;

OrderSend(request,result);
Print("OrderSendRetCode = ", result.retcode);
}

MQL4のOrderSend()のように引数を何個もとってもよいのですが、ここでは簡単のため、買いか売りかを指定する「type」と、売買ロット数「lots」だけを引数としてみます。

OrderSend()の使い方は前回の記事とだいたい同じです。違うところだけ説明します。

成行オーダーの場合、 request.action に、「TRADE_ACTION_DEAL」を代入します。

引数の「type」は、ENUM_ORDER_TYPEという型になっていますが、この引数はそのまま、request.typeに代入されます。ここでは、成行買いと成行売りのみを指定できるようにしますが、その識別子はそれぞれ、ORDER_TYPE_BUYORDER_TYPE_SELLとなっています。

request.priceは、売りと買いで異なるので、typeがORDER_TYPE_BUYの場合、買いなので、Askを、typeがORDER_TYPE_SELLの場合、売りなので、Bidを代入するようにします。

もう1つ、EAを作成する際に利用する関数として、オープンポジションのロット数を求める関数を作っておきます。ここでは、買いポジションの場合、プラス売りポジションの場合、マイナスの値としてロット数を返す関数にしてみます。

// オープンポジションのロット数
double OpenLots()
{
double lots = 0.0;
if(PositionSelect(_Symbol))
{
lots = PositionGetDouble(POSITION_VOLUME);
if(PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_SELL) lots = -lots;
}
return(lots);
}

まず、PositionSelect(_Symbol)は、挿入したチャートの通貨ペアでオープンポジションがあるかどうかを判別する関数で、オープンポジションがあれば trueを返し、なければfalse を返します。

オープンポジションがある場合、PositionGetDouble(POSITION_VOLUME)でロット数を求めます。

ただし、売りポジションの場合、マイナスの値として返すために、PositionGetInteger(POSITION_TYPE)でポジションのタイプを求め、それが、POSITION_TYPE_SELL(売りポジション)の場合、lotsをマイナスにします。

以上、二つの関数を作ってみましたが、これらをテストするための簡単なスクリプトプログラムを次に示します。

input double Lots = 0.1;
input int Slippage = 2;
double Bid, Ask;

void OnStart()
{
if(!RefreshRates()) return;

Print("Open Lots = ", OpenLots());

int ret = MessageBox("Buy at market", "TradeTest", MB_OKCANCEL);
if(ret == IDOK) OrderSendMarket(ORDER_TYPE_BUY, Lots);

ret = MessageBox("Sell at market", "TradeTest", MB_OKCANCEL);
if(ret == IDOK) OrderSendMarket(ORDER_TYPE_SELL, Lots);
}

// レートの更新
bool RefreshRates()
{
MqlTick tick;
if(!SymbolInfoTick(_Symbol, tick)) return(false);
Bid = tick.bid;
Ask = tick.ask;
return(true);
}

// 成行オーダー
void OrderSendMarket(ENUM_ORDER_TYPE type, double lots)
{
MqlTradeRequest request;
MqlTradeResult result;

request.action = TRADE_ACTION_DEAL;
request.symbol = _Symbol;
if(type == ORDER_TYPE_BUY) request.price = Ask;
else if(type == ORDER_TYPE_SELL) request.price = Bid;
request.deviation = Slippage;
request.volume = lots;
request.type = type;

OrderSend(request,result);
Print("OrderSendRetCode = ", result.retcode);
}

// オープンポジションのロット数
double OpenLots()
{
double lots = 0.0;
if(PositionSelect(_Symbol))
{
lots = PositionGetDouble(POSITION_VOLUME);
if(PositionGetInteger(POSITION_TYPE) == POSITION_TYPE_SELL) lots = -lots;
}
return(lots);
}

まず、以前の記事で説明したRefreshRates()でBid、Askを更新します。

次に、OpenLots()でオープンポジションのロット数を表示します。

そして、

OrderSendMarket(ORDER_TYPE_BUY, Lots);
OrderSendMarket(ORDER_TYPE_SELL, Lots);

成行き買いオーダーと、成行き売りオーダーを実行しますが、実行するかどうかはユーザーが選択できるように、MessageBox()関数でメッセージボックスを表示します。ここで、Okボタンを押すと、実際にオーダーが実行されるようになっています。

このプログラムで実際に売買を行ってみて、それぞれの関数の動きを確認してみてください。但し、言うまでもないことですが、このプログラムは必ずデモ口座で行ってくださいね。

これでようやくEAを作成する準備ができました。次回は簡単なEAを作成してみます。

Posted at 11時54分 パーマリンク


2010年09月06日(月)

MQL5でEA(2) [MetaTrader5]

今回はEAに欠かせないトレードに関する関数についてみてみましょう。

MQL4では、トレードに関して以下の4つの関数が用意されていました。

OrderSend() - 成行、指値、逆指値売買オーダーの送信
OrderClose() - オープンポジションの決済
OrderDelete() - 指値、逆指値の待機オーダーのキャンセル
OrderModify() - オーダーの変更

MQL5では、これらのトレードに関する機能は、一つの関数OrderSend()に集約されています。但し、このOrderSend()という関数は、MQL4の場合と同じ名前ですが、使い方は全く違います

まず、関数の宣言ですが、
bool  OrderSend(
MqlTradeRequest& request, // query structure
MqlTradeResult& result // structure of the answer
);

となっています。たったこれだけです。つまり、引数は二つしかないのです。

但し、引数の型は、それぞれ「MqlTradeRequest」と、「MqlTradeResult」となっています。

MqlTradeRequest、MqlTradeResultという型なんて聞いたことがないと思いますが、これはデータ型ではなく、MQL5で予め定義されている構造体の識別名なのです。

それぞれの構造体は以下のように定義されています。

struct MqlTradeRequest
{
ENUM_TRADE_REQUEST_ACTIONS action; // Trade operation type
ulong magic; // Expert Advisor ID (magic number)
ulong order; // Order ticket
string symbol; // Trade symbol
double volume; // Requested volume for a deal in lots
double price; // Price
double stoplimit; // StopLimit level of the order
double sl; // Stop Loss level of the order
double tp; // Take Profit level of the order
ulong deviation; // Maximal possible deviation from the requested price
ENUM_ORDER_TYPE type; // Order type
ENUM_ORDER_TYPE_FILLING type_filling; // Order execution type
ENUM_ORDER_TYPE_TIME type_time; // Order execution time
datetime expiration; // Order expiration time (for the orders of ORDER_TIME_SPECIFIED type)
string comment; // Order comment
};

struct MqlTradeResult
{
uint retcode; // Operation return code
ulong deal; // Deal ticket, if it is performed
ulong order; // Order ticket, if it is placed
double volume; // Deal volume, confirmed by broker
double price; // Deal price, confirmed by broker
double bid; // Current Bid price
double ask; // Current Ask price
string comment; // Broker comment to operation (by default it is filled by the operation description)
};

OrderSend()の仕組みは、大雑把に言うとこうです。MqlTradeRequestの構造体変数でオーダーの種類や価格、SL、TPを指定してOrderSend()に渡し、その結果がMqlTradeResultの構造体変数に格納されて返ってくるといった感じです。

ここでは、それぞれの構造体の詳しい説明は省略します。とりあえず、指値買いオーダーを送信する例についてみてみます。

まずは、MqlTradeRequest、MqlTradeResultの構造体変数を宣言します。
MqlTradeRequest request;
MqlTradeResult result;

この例では、requestresult というのが変数名ですが、必ずしもこの名前にする必要はありません。

次に request という構造体変数のそれぞれのフィールドに適切な値を代入します。

action」というフィールドで、成行、指値、修正、キャンセルなどの指示を行います。それぞれ識別子が決まっており、指値、逆指値オーダーの場合、「TRADE_ACTION_PENDING」を代入します。
request.action = TRADE_ACTION_PENDING;

symbol」というフィールドには、対象となる通貨ペアを代入します。通常は、
request.symbol = _Symbol;

と指定すれば、プログラムを挿入したチャートの通貨ペアとなります。

volume」は売買ロット数です。ここでは、0.1ロットを指定してみます。
request.volume = 0.1;

price」は指値の価格です。ここでは、USD/JPYを対象として80円に設定してみます。
request.price = 80.00;

type」というフィールドでは、買い、売りなどのオーダーの種類を指定します。指値買いの場合、「ORDER_TYPE_BUY_LIMIT」を指定します。
request.type = ORDER_TYPE_BUY_LIMIT;

これで必要最低限の設定は終わりましたので、OrderSend()を実行します。
OrderSend(request,result);

これで実際に指値オーダーが入ればOKですが、うまくいかない場合には、エラーコードを表示させると原因がつかみやすいでしょう。

OrderSend()のエラーコードは、resultのretcodeフィールドに格納されて戻ってきます。
Print("retcode = ",result.retcode);

のように表示させれば、ToolboxウィンドウのExpertsタブにエラーコードが表示されます。

画像(450x286)・拡大画像(800x510)

このように「retcode = 10009」となればOKです。10009というコードはオーダーが正常に実行されたことを意味します。

ただ、その下の行では、「retcode = 10027」となっています。これは、AutoTdradingが無効になっていて、オーダーが送信できなかったということを表します。スクリプトプログラムでも、オーダーを実行するためにはツールバーのAutoTradingのボタンを押して有効にしておく必要があります。

result.retcode は、他にも様々なエラーに対応したコードを返します。詳しくは、MQL5のレファレンスマニュアルのReturn Codes of the Trade Serverを参照してください。

最後に、今回説明したプログラムリストをつけておきます。

void OnStart()
{
MqlTradeRequest request;
MqlTradeResult result;

request.action = TRADE_ACTION_PENDING;
request.symbol = _Symbol;
request.volume = 0.1;
request.price = 80.0;
request.type = ORDER_TYPE_BUY_LIMIT;

OrderSend(request,result);
Print("retcode = ",result.retcode);
}

Posted at 15時20分 パーマリンク


2010年08月30日(月)

MQL5でEA(1) [MetaTrader5]

さて、今回からMQL5でEAを作成してみます。

「EA」は「Expert Advisor」の略で、日本語に直訳すれば「専門の相談員」となります。でも、これでは意味がわからないので、「EA」という言葉は普及しないかなと思っていたのですが、今ではメタトレーダーの自動売買プログラムという意味ですっかり定着したようです。

MQL5のEAも他のプログラム同様、MQL4とは互換性がないので、何回かにわけて説明していきます。

まず、メタエディターからFile - Newを選んでExpert Advisorを選択すると、以下のような新規プログラムが作成されます。

//+------------------------------------------------------------------+
//| Expert initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//---

//---
return(0);
}
//+------------------------------------------------------------------+
//| Expert deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
//---

}
//+------------------------------------------------------------------+
//| Expert tick function |
//+------------------------------------------------------------------+
void OnTick()
{
//---

}
//+------------------------------------------------------------------+

ここで、OnInit()、OnDeinit()、OnTick()の3つの関数があります。OnInit()、OnDeinit()はカスタム指標プログラムで出てきたものと同じで、それぞれプログラムの最初と最後に呼ばれる関数です。

OnTick()というのは初めて出てきましたが、これは MQL4での start()と同じものです。ティック毎に実行される関数です。

今回はまず準備として、MQL4で定義済み変数としてすぐに使えたものをMQL5用に用意しておきましょう。

最初にBidとAskです。BidとAskはプログラム全体で使えるように外部変数として宣言しておきます。

そして、以前の記事のように構造体MqlTickSymbolInfoTick()という関数を使って取得します。

ただ、これらを書く場所ですが、レートの更新はティック毎だけでなく、トレードの直前に行うこともあるので、RefreshRates()という関数(これはMQL4では組込み関数でした)を作って、そこに書いておくことにします。

以下のリストは、ティック毎にBid、Askを表示させるだけのEAです。

double Bid, Ask;

// 初期化関数
int OnInit()
{
return(0);
}

// 終了関数
void OnDeinit(const int reason)
{
}

// ティック関数
void OnTick()
{
if(!RefreshRates()) return;
Print("Bid=", Bid);
Print("Ask=", Ask);
}

// レートの更新
bool RefreshRates()
{
MqlTick tick;
if(!SymbolInfoTick(_Symbol, tick)) return(false);
Bid = tick.bid;
Ask = tick.ask;
return(true);
}

いくつかif文が出てきますが、これらは「念のため」といったところです。

SymbolInfoTick()は、正常にレートが取得できなかった場合にfalseを返すので、その場合RefreshRates()もfalseを返すようにしています。なお、

if(!SymbolInfoTick(_Symbol, tick)) return(false);

は、
if(SymbolInfoTick(_Symbol, tick) == false) return(false);

と同じ意味です。

同じく
if(!RefreshRates()) return;


if(RefreshRates() == false) return;

と同じ意味です。

ここで、return に戻り値がついていないのは、Ontick()void(戻り値なし)として宣言されているからです。

RefreshRates()でレート更新ができなかった場合は、それ以降のプログラムをスキップしてOnTick()関数を終了します。

次にチャートの4本値です。カスタム指標プログラムでは、OnCalculate()関数の引数としてOpen[]、High[]、Low[]、Close[]などの配列が使えたのですが、EAの場合、そのままでは使えません。

EAで4本値を使う方法について、Close[]を例にとって説明します。

まずは、Close[]を外部変数として宣言します。
double Close[];

そして、OnInit()中に、
ArraySetAsSeries(Close, true);

と書き、Close[]を時系列配列(最新のデータがClose[0]、1本前のデータがClose[1]・・・)に設定します。

そして、RefreshRates()関数中に、CopyClose()という関数を使い、終値配列をClose[]配列にコピーします。このCopyClose()関数は、前回CopyBuffer()関数と同じような使い方をします。
CopyClose(_Symbol, _Period, 0, count, Close)

と書くと、挿入したチャートの通貨ペア、タイムフレームにおける終値配列の最新の位置(0)からcount個分をClose[]配列にコピーします。

同様にOpen[]、Low[]、High[]の場合、CopyOpen()、CopyLow()、CopyHigh()という関数を使います。

以下のリストは、countを10とし、10個分の終値を表示させるプログラムです。

double Bid, Ask;
double Close[];

// 初期化関数
int OnInit()
{
ArraySetAsSeries(Close, true);
return(0);
}

// 終了関数
void OnDeinit(const int reason)
{
}

// ティック関数
void OnTick()
{
if(!RefreshRates()) return;
Print("Bid=", Bid);
Print("Ask=", Ask);
for(int i=0; i<10; i++) Print("Close[", i, "]=", Close[i]);
}

// レートの更新
bool RefreshRates()
{
MqlTick tick;
if(!SymbolInfoTick(_Symbol, tick)) return(false);
Bid = tick.bid;
Ask = tick.ask;

int count = 10;
if(CopyClose(_Symbol, _Period, 0, count, Close) < count) return(false);
return(true);
}

CopClose()もCopyBuffer()と同様、実際にコピーしたデータの個数を返すので、それがcountより少ない場合、エラーとしてfalseを返しています。

これで、プログラム中で終値をClose[0]、Close[1]などと参照することができるようになりました。

次回はトレードに関する関数について見ていきます。

Posted at 14時58分 パーマリンク


過去の記事へ

ページのトップへ ページのトップへ

Sponsor AD

シストレナビモバイル

シストレナビモバイル
ケータイでバーコードを読み取りアクセス(詳細はこちら

プロフィール

豊嶋久道

2003年よりFX取引を始め、システムトレードの道へ。最近ではFXオプション取引も含めたトレーディングシステムの研究を行っている。システムトレードを基礎から正しく理解するための情報を発信する予定。

活動状況・Website

ToyolabFX
Toyolab FX-手ぶらで為替取引
FXトレーディング研究所。
FXメタトレーダー入門
FXメタトレーダー入門
最先端システムトレードソフト使いこなし術。
FXメタトレーダー実践プログラミング
FXメタトレーダー実践プログラミング
システム開発過程を段階的に学ぶ。

2010/9

      1 2 3 4
5 6 7 8 9 10 11
12 13 14 15 16 17 18
19 20 21 22 23 24 25
26 27 28 29 30    

PHOTO

Excelでヒストグラムの作成

Excelでヒストグラムの作成

カテゴリーリスト

最近の記事

スポンサードリンク

検索


当サイトコメントについて

当コメントは情報提供のみを目的として作成されたものであり、投資に関してはご自身でご判断くださいますようお願い致します。また、当資料は著作物であり著作権法により保護されております。無断で全文または一部を転載することはできません。

RSS1.0

[Login]


powered by a-blog
Copyright (C) 2008 PhiConcept,Inc. All rights reserved.