さて、今回からMQL5でEAを作成してみます。

「EA」は「Expert Advisor」の略で、日本語に直訳すれば「専門の相談員」となります。でも、これでは意味がわからないので、「EA」という言葉は普及しないかなと思っていたのですが、今ではメタトレーダーの自動売買プログラムという意味ですっかり定着したようです。

MQL5のEAも他のプログラム同様、MQL4とは互換性がないので、何回かにわけて説明していきます。

まず、メタエディターからFile - Newを選んでExpert Advisorを選択すると、以下のような新規プログラムが作成されます。

//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   
//---
   return(0);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---
   
  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   
  }
//+------------------------------------------------------------------+

ここで、OnInit()、OnDeinit()、OnTick()の３つの関数があります。OnInit()、OnDeinit()はカスタム指標プログラムで出てきたものと同じで、それぞれプログラムの最初と最後に呼ばれる関数です。

OnTick()というのは初めて出てきましたが、これは MQL4での start()と同じものです。ティック毎に実行される関数です。

今回はまず準備として、MQL4で定義済み変数としてすぐに使えたものをMQL5用に用意しておきましょう。

最初にBidとAskです。BidとAskはプログラム全体で使えるように外部変数として宣言しておきます。

そして、以前の記事のように構造体MqlTickとSymbolInfoTick()という関数を使って取得します。

ただ、これらを書く場所ですが、レートの更新はティック毎だけでなく、トレードの直前に行うこともあるので、RefreshRates()という関数（これはMQL4では組込み関数でした）を作って、そこに書いておくことにします。

以下のリストは、ティック毎にBid、Askを表示させるだけのEAです。

double Bid, Ask;

// 初期化関数
int OnInit()
{
   return(0);
}

// 終了関数
void OnDeinit(const int reason)
{
}

// ティック関数
void OnTick()
{
   if(!RefreshRates()) return;
   Print("Bid=", Bid); 
   Print("Ask=", Ask); 
}
  
// レートの更新
bool RefreshRates()
{
   MqlTick tick;
   if(!SymbolInfoTick(_Symbol, tick)) return(false);
   Bid = tick.bid;
   Ask = tick.ask;
   return(true);
}

いくつかif文が出てきますが、これらは「念のため」といったところです。

SymbolInfoTick()は、正常にレートが取得できなかった場合にfalseを返すので、その場合RefreshRates()もfalseを返すようにしています。なお、

if(!SymbolInfoTick(_Symbol, tick)) return(false);

は、

if(SymbolInfoTick(_Symbol, tick) == false) return(false);

と同じ意味です。

同じく

if(!RefreshRates()) return;

も

if(RefreshRates() == false) return;

と同じ意味です。

ここで、return に戻り値がついていないのは、Ontick()がvoid（戻り値なし）として宣言されているからです。

RefreshRates()でレート更新ができなかった場合は、それ以降のプログラムをスキップしてOnTick()関数を終了します。

次にチャートの４本値です。カスタム指標プログラムでは、OnCalculate()関数の引数としてOpen[]、High[]、Low[]、Close[]などの配列が使えたのですが、EAの場合、そのままでは使えません。

EAで４本値を使う方法について、Close[]を例にとって説明します。

まずは、Close[]を外部変数として宣言します。

double Close[];

そして、OnInit()中に、

ArraySetAsSeries(Close, true);

と書き、Close[]を時系列配列（最新のデータがClose[0]、1本前のデータがClose[1]・・・）に設定します。

そして、RefreshRates()関数中に、CopyClose()という関数を使い、終値配列をClose[]配列にコピーします。このCopyClose()関数は、前回のCopyBuffer()関数と同じような使い方をします。

CopyClose(_Symbol, _Period, 0, count, Close)

と書くと、挿入したチャートの通貨ペア、タイムフレームにおける終値配列の最新の位置（0）からcount個分をClose[]配列にコピーします。

同様にOpen[]、Low[]、High[]の場合、CopyOpen()、CopyLow()、CopyHigh()という関数を使います。

以下のリストは、countを10とし、10個分の終値を表示させるプログラムです。

double Bid, Ask;
double Close[];

// 初期化関数
int OnInit()
{
   ArraySetAsSeries(Close, true);
   return(0);
}

// 終了関数
void OnDeinit(const int reason)
{
}

// ティック関数
void OnTick()
{
   if(!RefreshRates()) return;
   Print("Bid=", Bid); 
   Print("Ask=", Ask); 
   for(int i=0; i<10; i++) Print("Close[", i, "]=", Close[i]);
}
  
// レートの更新
bool RefreshRates()
{
   MqlTick tick;
   if(!SymbolInfoTick(_Symbol, tick)) return(false);
   Bid = tick.bid;
   Ask = tick.ask;
   
   int count = 10;
   if(CopyClose(_Symbol, _Period, 0, count, Close) < count) return(false);
   return(true);
}

CopClose()もCopyBuffer(）と同様、実際にコピーしたデータの個数を返すので、それがcountより少ない場合、エラーとしてfalseを返しています。

これで、プログラム中で終値をClose[0]、Close[1]などと参照することができるようになりました。

次回はトレードに関する関数について見ていきます。

カスタム指標プログラムでテクニカル指標を表示させる最も簡単な方法は、MQL5に既に組み込まれている関数を使うことです。

MQL5にも、MQL4のようによく使うテクニカル指標が組み込み関数として用意されています。例えば、移動平均線を算出する関数はiMA()です。

MQL4では、iMA()などの組み込みテクニカル指標関数は、その指標の値そのものが関数の戻り値だったので、

Buf[i] = iMA(NULL, 0, MAPeriod, 0, MODE_SMA, PRICE_CLOSE, i); 

のように指標バッファ用の配列に直接代入するだけで利用することができました。

しかし、MQL5では、同じiMA()を使うにも、いくつかの手順を踏まなくてはいけません。

まずは、iMA()を利用して移動平均線を表示するMQL5プログラムを示します。

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1

#property indicator_label1  "MA"
#property indicator_type1   DRAW_LINE
#property indicator_color1  Red
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2

// パラメータ
input int MAPeriod = 20;

// 指標バッファ
double Buf[];

// テクニカル指標ハンドル
int hMA;

// 初期化関数
int OnInit()
{
   // 指標バッファの割り当て
   SetIndexBuffer(0, Buf, INDICATOR_DATA);

   // テクニカル指標の初期化
   hMA = iMA(NULL, 0, MAPeriod, 0, MODE_SMA, PRICE_CLOSE);

   return(0);
}

// 終了関数
void OnDeinit(const int reason)
{
   // テクニカル指標の解放
   IndicatorRelease(hMA);
}

// 開始関数
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime& Time[],
                const double& Open[],
                const double& High[],
                const double& Low[],
                const double& Close[],
                const long& Tick_volume[],
                const long& Volume[],
                const int& Spread[])
{
   // バッファのコピー
   CopyBuffer(hMA, 0, 0, rates_total, Buf);
   return(rates_total);
}

順に説明していきます。

// パラメータ
input int MAPeriod = 20;

これは、iMA()で利用する「移動平均の期間」を変えるための変数です。チャート挿入時に現れるプロパティ画面のInputsタブ(下図)で値を変えることができます。

このような用途の場合、MQL4では「extern」をつけて宣言していましたが、MQL5では「input」というキーワードに変わりました。

次に、問題のiMA()の使い方ですが、

// テクニカル指標ハンドル
int hMA; 

に注目してください。

テクニカル指標ハンドルとは聞きなれない言葉ですが、MQL5では、外部変数として宣言したハンドルと呼ばれる変数を介してテクニカル指標を扱うようになっているのです。

プログラム中では、「hMA」という変数は以下の３箇所に出てきます。

OnInit()中
// テクニカル指標の初期化
hMA = iMA(NULL, 0, MAPeriod, 0, MODE_SMA, PRICE_CLOSE); 

OnDeinit()中
// テクニカル指標の解放
IndicatorRelease(hMA); 

OnCalculate()中
// バッファのコピー
CopyBuffer(hMA, 0, 0, rates_total, Buf); 

手順としては、まず、OnInit()関数の中でiMA()を呼び出し、テクニカル指標の初期化を行います。

テクニカル指標の初期化とは、プログラム内部に移動平均用の配列を確保し、チャート全体の移動平均の値を格納しておくことです。

iMA()のパラメータはMQL4の場合とほぼ同じです。この例では、挿入したチャート上での終値に対する単純移動平均(SMA)を求めます。

但し、iMA()の戻り値は移動平均の値ではなく、このテクニカル指標を特定するための値（ハンドル）です。

つまり、MQL4のように各バーにおける移動平均の値をいちいちiMA()を呼び出して算出するのではなく、移動平均の値は内部の配列に自動的に算出されるわけです。

この移動平均の入っている配列をそのまま表示すれば簡単なのですが、残念ながらこれを直接表示させることはできず、表示用の指標バッファとして割り当てられた配列にコピーしてやる必要があるのです。

それが、OnCalculate()中のCopyBuffer()という関数で行っていることです。CopyBuffer()では、最初の引数にコピーしたいテクニカル指標のハンドル、２番目の引数にテクニカル指標のインデックス（移動平均の場合、指標は１本しかないので、０を指定）を代入します。

３番目と４番目の引数は変数の型によって意味が違ってくるのですが、両方intの場合、コピーしたいテクニカル指標の位置とコピーしたい個数を指定します。0, rates_total の場合、0の位置からrates_total個の指標データをコピーすることを意味します。

そして、５番目の引数はコピー先の配列名です。ここでは、SetIndexBuffer()で割り当てた「Buf」を指定します。

これで、rates_total個、つまりチャート上のすべての移動平均の値をBuf[]にコピーすることができたわけです。

最後にOnDeinit()（MQL4のdeinit()と同じ）中でIndicatorRelease(hMA)を呼んでいますが、これは、hMAで確保した配列を解放することを意味します。このプログラムが終了すれば、移動平均の配列は不要となるので、メモリの消費を防ぐために解放しておくのです。

以上が組み込みテクニカル指標関数の最も簡単な使い方です。コンパイルしてチャートに挿入すると次のように表示されます。

但し、このままでは、OnCalculate()を呼ぶ毎にチャート上のすべての移動平均の値をコピーします。新しいバーのために必要な分だけコピーするには、CopyBuffer()でコピーする個数を変えてやる必要があります。

ここで注意することは、Buf[]は、最も古いバーからインデックスが振られている配列なのに対して、hMAで確保されている内部配列は最新のバーから古い方にインデックスが振られている「時系列配列」だということです。

ですから、CopyBuffer()で、0からrates_total個というのは、最新のバーからrates_total個ということになります。そこで、rates_tatalをcountに変えると、最新のバーからcount個のデータをコピーすることになります。

プログラムは次のように追加・修正します。

int limit = prev_calculated; 
if(prev_calculated > 0) limit--;
int count = rates_total-limit;

// バッファのコピー
if(CopyBuffer(hMA, 0, 0, count, Buf) < count) return(0); 

前回の記事で説明したlimitという変数を使い、count=rates_total-limit とします。すると、最初はcount=rates_total となり、すべてのデータをコピーしますが、２回目からはcount=1となるので、最新のバーのみのコピーとなります。

なお、ここでif文になっているのは、CopyBuffer()の戻り値が実際にコピーできた指標データの個数になるのですが、それが指定したcountより少ない場合、エラーなので、return(0)として次回の実行時にコピーし直すためです。

簡単な方法と言いながら、ちょっと長くなってしまいました。配列のコピーについては、別の機会にも出てきますので、そのときにまた説明します。

OnCalculate()関数の引数の意味がわかったところで、今回は、簡単なカスタム指標プログラムを作ってみましょう。

といっても終値をラインで結んでいくという超簡単なものです。（実用性はありません^^;）

MQL5のプログラムは次のように書けます。

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Close
#property indicator_label1  "Close"
#property indicator_type1   DRAW_LINE
#property indicator_color1  Red
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2
//--- indicator buffers
double BufClose[];

int OnInit()
{
   SetIndexBuffer(0, BufClose, INDICATOR_DATA);
   return(0);
}

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime& Time[],
                const double& Open[],
                const double& High[],
                const double& Low[],
                const double& Close[],
                const long& Tick_volume[],
                const long& Volume[],
                const int& Spread[])
{
   for(int i=0; i<rates_total; i++)
   {
      BufClose[i] = Close[i];
   }

   return(rates_total);
}

順番に説明していきます。

#property indicator_chart_window

これは、指標をチャートウィンドウに表示するための指定ですね。MQL4と同じです。

#property indicator_buffers 1
#property indicator_plots   1

これは、指標バッファの数を指定する命令です。MQL4では、indicator_buffersだけでしたが、MQL5では、indicator_plotsで、実際に表示させる指標の数も指定するようになりました。

#property indicator_label1  "Close"
#property indicator_type1   DRAW_LINE
#property indicator_color1  Red
#property indicator_style1  STYLE_SOLID
#property indicator_width1  2 

では、指標の表示スタイルを設定しています。indicator_color1、indicator_style1、indicator_width1などはMQL4と同じですが、MQL5では、indicator_label1、indicator_type1で指標のラベルや指標の種類も指定できるようになりました。

double BufClose[]; 

これが指標バッファ用の配列で、MQL4と同じく外部変数として宣言します。

次にOnInit()関数で、

SetIndexBuffer(0, BufClose, INDICATOR_DATA); 

のように、BufClose[]という配列を指標バッファに割り当てます。この仕組みもMQL4と同じですが、この関数の引数がひとつ増えて、最後にINDICATOR_DATAを指定するようになりました。

MQL5では、指標バッファに格納されるのが指標の値だけでなく、指標の色も格納できるようになったので、どちらを格納するかを区別するための指定です。

最後にOnCalculate()中に、指標バッファに割り当てられた配列BufClose[]の各要素に、表示させたい指標の値を代入すれば完成です。

簡単には、チャート上のすべてのバーに対応する指標値を代入すればよいので、

for(int i=0; i<rates_total; i++)
{
   BufClose[i] = Close[i];
} 

と書けます。つまり、BufClose[0]からBufClose[rates_total-1]までにそれぞれのバーの終値を代入したことになります。

但し、前回説明したように、BufClose[rates_total-1]が最新のバーの指標値だということに注意してください。

このプログラムをコンパイルして、適当なチャートにアタッチすると、下のチャートのように終値を結んだ指標が表示されます。

ただ、このままでは、OnCalculate()を呼び出すたびにチャート上のすべての指標値を書き直すことになるので、２回目以降は最新のバーのみ書き直すようにすると無駄な処理を減らすことができます。

そのために、次のようにプログラムを追加します。

int limit = prev_calculated;
if(prev_calculated > 0) limit--;

for(int i=limit; i<rates_total; i++)
{
   BufClose[i] = Close[i];
} 

指標値を代入するインデックスを0からではなく、limitから始めます。limit には、prev_calculatedを代入しておきます。

prev_calculated は、チャートにアタッチした直後は、0となっており、その後は前回計算したバーの総数が代入されます。

なので、prev_calculatedが0の場合は、limitも0のままで、0からrates_total-1までのバーの指標を表示します。

２回目以降は、prev_calculatedの値が0より大きいので limitを1だけ減らしておきます。これで、limit=rates_total-1 となるので、常に最新のバーの指標値を更新することができます。

このあたりのプログラムは色々な書き方があり、MQL4と同様、初心者向けに説明するのは難しいところです。

説明の仕方を考えながら、次回に続きます・・・